%
% file:	   href-publist-gerunsrt.bst
% needs:   pdflatex, hyperref
% author:  Alexander Wolff (derived from publist-gerunsrt.bst)
% date:    05.07.2002
%
% - This bibtex style is a variant of the bibtex style publist-gerunsrt.bst.
%
% - Additionally to the functionality of publist-gerunsrt.bst we check 
%   whether a bibitem has a pdf postscript or url entry, i.e. a URL
%   pointing to a file in pdf or postscript format or some other URL.  
%   If this is the case, we introduce a hyperlink from the
%   title of the bibitem to that URL.  This makes it possible to 
%   download the pdf/ps file from viewers like acroread, xpfd or xdvi,
%   if the main document is processed with pdflatex instead of latex.
%   You need to include the latex package hyperref in the main document:
%   \usepackage{hyperref}
%   Include hyperref last!
%
% For illustration: a typical bibitem using unsrt.bst is
%
% \bibitem{pssw-lpw-01i}
% Sheung-Hung Poon, Chan-Su Shin, Tycho Strijk, and Alexander Wolff.
% \newblock Labeling points with weights.
% \newblock In Peter Eades and Tadao Takaoka, editors, {\em Proc. 12th Annual
%   International Symposium on Algorithms and Computation (ISAAC'01)}, volume
%   2223 of {\em Lecture Notes in Computer Science}, pages 610--622,
%   Christchurch, 19--21~December 2001. Springer-Verlag.
%
% With href-publist-gerunsrt.bst, pdf entry "http://www.bla.de/pssw.pdf", 
% and yourname = "Alexander Wolff" the same bibitem will be formatted
% as follows: 
% 
% \bibitem{pssw-lpw-01i}
% \href{http://www.bla.de/pssw.pdf}{\bgroup\scshape Labeling points with weights\egroup}.
% \newblock \Btxinlong{}\ Peter Eades \btxandlong{}\ Tadao Takaoka\
% (\btxeditorslong{}): {\em Proc. 12th Annual International Symposium on
% Algorithms and Computation (ISAAC'01)}, \btxvolumelong{}\ 2223
% \btxofserieslong{}\ {\em Lecture Notes in Computer Science}, \btxpageslong{}\
% 610--622, Christchurch, 19.--21.~\btxmondeclong{} 2001. Springer-Verlag.
% \newblock In Zusammenarbeit mit Sheung-Hung Poon, Chan-Su Shin \btxandlong{}\
% Tycho Strijk.

FUNCTION{yourname}
{
"alexander wolff"
}

ENTRY
  { address
    author
    booktitle
    chapter
    edition
    editor
    howpublished
    institution
    journal
    key
    language
    month
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
    pdf
    postscript
    url
  }
  {}
  { label }

INTEGERS { output.state before.all mid.sentence after.sentence after.block before.title removed }

STRINGS { s t language.state language.temp }

FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.sentence :=
  #3 'after.block :=
  #4 'before.title :=
  "nostate" 'language.state :=
}

FUNCTION {language.state.test}
{ 
  'language.temp :=
  language.temp language.state =
    { #1 }
    { #0 }
  if$
}


FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {output.nonnull}
{ 's :=
  output.state mid.sentence =
    { ", " * write$ }
    { output.state after.block =
        { add.period$ write$
          newline$
          "\newblock " write$
        }
        { output.state before.all =
            'write$
            % next if is for use with `new' FUNCTION {after.authors}
            { output.state before.title =
                { ": " * write$ }
                { add.period$ " " * write$ }
              if$
            }
          if$
        }
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {output.bibitem}
{ newline$
  language empty$
    'skip$
    { language.state language =
        'skip$
        { "\selectlanguage{\" language * "}" * write$
          newline$
        }
      if$
      language 'language.state :=
    }
  if$
  "\bibitem{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {fin.entry}
{ add.period$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { after.block 'output.state := }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
        'skip$
        { after.sentence 'output.state := }
      if$
    }
  if$
}

% new one -> sets what is specified in FUNCTION {output.nonnull}
% if `before.title 'output.state = ... if$' is true
FUNCTION {after.authors}
{ output.state before.all =
    'skip$
    { before.title 'output.state := }
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkc}
{ empty$
  swap$ empty$
  and
    'skip$
    'after.authors
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {new.sentence.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "{\em " swap$ * "}" * }
  if$
}

FUNCTION {smallcaps}
{ duplicate$ empty$
    { pop$ "" }
    { "{\sc " swap$ * "}" * }
  if$
}

INTEGERS { nameptr namesleft numnames }

% NEW
FUNCTION {format.coauthor.names}
{ 's :=
  #1 'nameptr :=
  #0 'removed :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
  namesleft #1 =		%% If there is just one name, no co-authors...
				%% We assume *you* are the author...
    {
      s #1 "{ff }{vv }{ll}" format.name$ "l" change.case$ yourname =
	{#1 'removed :=}
	{}
      if$ 
      ""
    }
    {
      { namesleft #0 > }
        { 
          s nameptr "{ff }{vv }{ll}" format.name$ "l" change.case$ yourname =
            { #1 'removed := }     %% nothing to write
            {
	      s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ 't :=
              nameptr #1 > removed #1 < and nameptr #2 > or
	        { 
		  namesleft #1 > removed #1 = and namesleft #2 > or
	            { ", " * t * }
% OLD
%		    { numnames #2 >
% NEW
		    { numnames #3 >
			{ "english" language.state.test
			  "USenglish" language.state.test
			  or
			     {"," * }
			     'skip$
			  if$
			}
			'skip$
		      if$
		      t "others" =
			{ " \btxetalshort{.}" * }
			{ " \btxandlong{}\ " * t * }
		      if$
	            }
	          if$
	        }
	        't
              if$
            }
          if$
          nameptr #1 + 'nameptr :=
          namesleft #1 - 'namesleft :=
        }
      while$
      "In Zusammenarbeit mit " swap$ *
    }
  if$  

  %% Last, we test if you are an author...
  removed #0 = {"You are not an author of " cite$ * warning$} {} if$
}

FUNCTION {format.names}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { nameptr #1 >
	% NEW
        { s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ 't :=
          namesleft #1 >
            { ", " * t * }
            { numnames #2 >
                { "english" language.state.test
                  "USenglish" language.state.test
                  or
                     {"," * }
                     'skip$
                  if$
                }
                'skip$
              if$
              t "others" =
                { " \btxetalshort{.}" * }
                { " \btxandlong{}\ " * t * }
              if$
            }
          if$
        }
	% NEW
        { s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ }
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.coauthors}
{ author empty$
    { "" }
    { author format.coauthor.names }
  if$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
    { "" }
    { editor format.names
      editor num.names$ #1 >
        { "\ (\btxeditorslong{})" * }
        { "\ (\btxeditorlong{})" * }
      if$
    }
  if$
}

% OLD
%
% FUNCTION {format.title}
% { title empty$
%     { "" }
%     { "english" language.state.test
%       "USenglish" language.state.test
%       or
%         { title "t" change.case$ smallcaps }
%         { title smallcaps }
%       if$
%     }
%   if$
% }

% NEW
FUNCTION {format.title}
{ title empty$
    { "" }
    { 
      pdf empty$
	{
	  postscript empty$
	    {
	      url empty$
		{ "" }
		{ "\href{" url "}%" * * write$ newline$ "{" }
	      if$
	    }
	    { "\href{" postscript "}%" * * write$ newline$ "{" }
	  if$
	}
        { "\href{" pdf "}%" * * write$ newline$ "{" }
      if$
      "\bgroup\scshape " title "t" change.case$ "\egroup" * * *
      pdf empty$ postscript empty$ url empty$ and and 
        { "" * }
        { "}" * }
      if$
    }
  if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
        { t #1 #2 substring$ "--" = not
            { "--" *
              t #2 global.max$ substring$ 't :=
            }
            {   { t #1 #1 substring$ "-" = }
                { "-" *
                  t #2 global.max$ substring$ 't :=
                }
              while$
            }
          if$
        }
        { t #1 #1 substring$ *
          t #2 global.max$ substring$ 't :=
        }
      if$
    }
  while$
}

FUNCTION {format.date}
{ year empty$
    { month empty$
        { "" }
        { "there's a month but no year in " cite$ * warning$
          month
        }
      if$
    }
    { month empty$
        'year
        { month " " * year * }
      if$
    }
  if$
}

FUNCTION {format.btitle}
{ title emphasize
}

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { "\ " }
  if$
  swap$ * *
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}
{ volume empty$
    { "" }
    { output.state after.block =
        { "\Btxvolumelong{}" }
        { "\btxvolumelong{}" }
      if$
      volume tie.or.space.connect
      series empty$
        'skip$
        { " \btxofserieslong{}\ " * series emphasize * }
      if$
      "volume and number" number either.or.check
    }
  if$
}

FUNCTION {format.number.series}
{ volume empty$
    { number empty$
        { series field.or.null }
        { output.state mid.sentence =
            { "\btxnumberlong{}" }
            { "\Btxnumberlong{}" }
          if$
          number tie.or.space.connect
          series empty$
            { "there's a number but no series in " cite$ * warning$ }
            { " \btxinserieslong{}\ " * series emphasize * }
          if$
        }
      if$
    }
    { "" }
  if$
}

FUNCTION {format.edition}
{ edition empty$
    { "" }
    { "english" language.state.test
      "USenglish" language.state.test
      or
        { output.state mid.sentence =
            { edition "l" change.case$ " \btxeditionlong{}" * }
            { edition "t" change.case$ " \btxeditionlong{}" * }
          if$
        }
        { edition " \btxeditionlong{}" * }
      if$
    }
  if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
        { #1 'multiresult := }
        { t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { "\btxpageslong{}" pages n.dashify tie.or.space.connect }
        { "\btxpagelong{}" pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.vol.num.pages}
{ volume field.or.null
  number empty$
    'skip$
    { "(" number * ")" * *
      volume empty$
        { "there's a number but no volume in " cite$ * warning$ }
        'skip$
      if$
    }
  if$
  pages empty$
    'skip$
    { duplicate$ empty$
        { pop$ format.pages }
        { ":" * pages n.dashify * }
      if$
    }
  if$
}

FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.pages
    { type empty$
        { "\btxchapterlong{}" }
        { "english" language.state.test
          "USenglish" language.state.test
          or
             { type "l" change.case$ }
             { type }
         if$
        }
      if$
      chapter tie.or.space.connect
      pages empty$
        'skip$
        { ", " * format.pages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.booktitle}
{ booktitle empty$
    { "" }
    { editor empty$
        { "\Btxinlong{}\ " booktitle emphasize * }
        { "\Btxinlong{}\ " format.editors * ": " * booktitle emphasize * }
      if$
    }
  if$
}

FUNCTION {empty.misc.check}
{ author empty$ title empty$ howpublished empty$
  month empty$ year empty$ note empty$
  and and and and and
    { "all relevant fields are empty in " cite$ * warning$ }
    'skip$
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      "english" language.state.test
      "USenglish" language.state.test
      or
        { type "t" change.case$ }
        { type }
      if$
    }
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "\Btxtechreplong{}" }
    'type
  if$
  number empty$
    { "english" language.state.test
      "USenglish" language.state.test
      or
        { type empty$
            { pop$ "\btxtechreplong{}" }
            { "t" change.case$ }
          if$
        }
        'skip$
      if$
    }
    { number tie.or.space.connect }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
        { "need key or journal for " cite$ * " to crossref " * crossref *
          warning$
          ""
        }
        { "\Btxinlong{}\ " journal emphasize * }
      if$
    }
    { "\Btxinlong{}\ " key emphasize * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.crossref.editor}
{ editor #1 "{ll}{, jj}{, ff}{~vv}" format.name$ smallcaps
  editor num.names$ duplicate$
  #2 >
    { pop$ " \btxetalshort{.}" * }
    { #2 <
        'skip$
        { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
            { " \btxetalshort{.}" * }
            { " \btxandlong{}\ " * editor #2 "{ff}{~vv}{~ll}{, jj}" format.name$ smallcaps * }
          if$
        }
      if$
    }
  if$
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "\Btxinlong{}\ "
    }
    { "\Btxvolumelong{}" volume tie.or.space.connect
      " \btxofserieslong{}\ " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
        { series empty$
            { "need editor, key, or series for " cite$ * " to crossref " *
              crossref * warning$
              "" *
            }
            { series emphasize * }
          if$
        }
        { key emphasize * }
      if$
    }
    { format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
        { booktitle empty$
            { "need editor, key, or booktitle for " cite$ * " to crossref " *
              crossref * warning$
              ""
            }
            { "\Btxinlong{}\ " booktitle emphasize * }
          if$
        }
        { "\Btxinlong{}\ " key emphasize * }
      if$
    }
    { "\Btxinlong{}\ " format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {article}
{ output.bibitem
  % OLD 
  % format.authors "author" output.check
  after.authors
  format.title "title" output.check
  new.block
  crossref missing$
    { journal 
      title missing$
        { emphasize }
        'skip$
      if$
      "journal" output.check 
      format.vol.num.pages output
      format.date "year" output.check
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  note output
  % NEW
  format.coauthors output
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
        { "author and editor" editor either.or.check }
        'skip$
      if$
    }
  if$
  after.authors
  % OLD
  % format.btitle "title" output.check
  % NEW
  format.title "title" output.check
  crossref missing$
    { format.bvolume output
      new.block
      format.number.series output
      new.sentence
      publisher "publisher" output.check
      address output
    }
    { new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  % OLD
  % format.authors output
  after.authors
  format.title "title" output.check
  howpublished address new.block.checkb
  howpublished output
  address output
  format.date output
  new.block
  note output
  % NEW
  format.coauthors output
  fin.entry
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
        { "author and editor" editor either.or.check }
        'skip$
      if$
    }
  if$
  after.authors
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      format.chapter.pages "chapter and pages" output.check
      new.block
      format.number.series output
      new.sentence
      publisher "publisher" output.check
      address output
    }
    { format.chapter.pages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  % OLD
  % format.authors "author" output.check
  after.authors
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.number.series output
      format.chapter.pages output
      new.sentence
      publisher "publisher" output.check
      address output
      format.edition output
      format.date "year" output.check
    }
    { format.incoll.inproc.crossref output.nonnull
      format.chapter.pages output
    }
  if$
  new.block
  note output
  % NEW
  format.coauthors output
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  % OLD
  % format.authors "author" output.check
  after.authors
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.number.series output
      format.pages output
      address empty$
        { organization publisher new.sentence.checkb
          organization output
          publisher output
          format.date "year" output.check
        }
        { address output.nonnull
          format.date "year" output.check
          new.sentence
          organization output
          publisher output
        }
      if$
    }
    { format.incoll.inproc.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  note output
  % NEW
  format.coauthors output
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
        'skip$
        { organization smallcaps output.nonnull
          address output
        }
      if$
    }
    { format.authors output.nonnull }
  if$
  after.authors
  % OLD
  % format.btitle "title" output.check
  % NEW
  format.title "title" output.check
  author empty$
    { organization empty$
        { address new.block.checka
          address output
        }
        'skip$
      if$
    }
    { organization address new.block.checkb
      organization output
      address output
    }
  if$
  format.edition output
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {mastersthesis}
{ output.bibitem
  % OLD
  % format.authors "author" output.check
  after.authors
  format.title "title" output.check
  new.block
  "\btxmastthesis{}" format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  % OLD
  % format.authors output
  title howpublished new.block.checkc
  format.title output
  howpublished new.block.checka
  howpublished output
  format.date output
  new.block
  note output
  % NEW
  format.coauthors output
  fin.entry
  empty.misc.check
}

FUNCTION {phdthesis}
{ output.bibitem
  % OLD
  % format.authors "author" output.check
  after.authors
  % OLD
  % format.btitle "title" output.check
  % NEW
  format.title "title" output.check
  new.block
  "\btxphdthesis{}" format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  editor empty$
    { organization smallcaps output }
    { format.editors output.nonnull }
  if$
  after.authors
  format.btitle "title" output.check
  format.bvolume output
  format.number.series output
  address empty$
    { editor empty$
        { publisher new.sentence.checka }
        { organization publisher new.sentence.checkb
          organization output
        }
      if$
      publisher output
      format.date "year" output.check
    }
    { address output.nonnull
      format.date "year" output.check
      new.sentence
      editor empty$
        'skip$
        { organization output }
      if$
      publisher output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  % OLD
  % format.authors "author" output.check
  after.authors
  format.title "title" output.check
  new.block
  format.tr.number output.nonnull
  institution "institution" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  % NEW
  format.coauthors output
  fin.entry
}

FUNCTION {unpublished}
{ output.bibitem
  % OLD
  % format.authors "author" output.check
  after.authors
  format.title "title" output.check
  new.block
  note "note" output.check
  format.date output
  % NEW
  format.coauthors output
  fin.entry
}

FUNCTION {default.type} { misc }

MACRO {jan} {"\btxmonjanlong{}"}

MACRO {feb} {"\btxmonfeblong{}"}

MACRO {mar} {"\btxmonmarlong{}"}

MACRO {apr} {"\btxmonaprlong{}"}

MACRO {may} {"\btxmonmaylong{}"}

MACRO {jun} {"\btxmonjunlong{}"}

MACRO {jul} {"\btxmonjullong{}"}

MACRO {aug} {"\btxmonauglong{}"}

MACRO {sep} {"\btxmonseplong{}"}

MACRO {oct} {"\btxmonoctlong{}"}

MACRO {nov} {"\btxmonnovlong{}"}

MACRO {dec} {"\btxmondeclong{}"}

MACRO {acmcs} {"ACM Computing Surveys"}

MACRO {acta} {"Acta Informatica"}

MACRO {cacm} {"Communications of the ACM"}

MACRO {ibmjrd} {"IBM Journal of Research and Development"}

MACRO {ibmsj} {"IBM Systems Journal"}

MACRO {ieeese} {"IEEE Transactions on Software Engineering"}

MACRO {ieeetc} {"IEEE Transactions on Computers"}

MACRO {ieeetcad}
 {"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}

MACRO {ipl} {"Information Processing Letters"}

MACRO {jacm} {"Journal of the ACM"}

MACRO {jcss} {"Journal of Computer and System Sciences"}

MACRO {scp} {"Science of Computer Programming"}

MACRO {sicomp} {"SIAM Journal on Computing"}

MACRO {tocs} {"ACM Transactions on Computer Systems"}

MACRO {tods} {"ACM Transactions on Database Systems"}

MACRO {tog} {"ACM Transactions on Graphics"}

MACRO {toms} {"ACM Transactions on Mathematical Software"}

MACRO {toois} {"ACM Transactions on Office Information Systems"}

MACRO {toplas} {"ACM Transactions on Programming Languages and Systems"}

MACRO {tcs} {"Theoretical Computer Science"}

READ

STRINGS { longest.label }

INTEGERS { number.label longest.label.width }

FUNCTION {initialize.longest.label}
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
    { label 'longest.label :=
      label width$ 'longest.label.width :=
    }
    'skip$
  if$
}

EXECUTE {initialize.longest.label}

ITERATE {longest.label.pass}

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}
